accueil — déluge

déluge fait de la musique avec le logiciel SuperCollider.
Sur ce site vous trouverez toutes ses activités artistiques et associatives.
Baladez-vous, je vous en prie.

hello, my name is déluge and I make music with SuperCollider. On this website you will find all my artistic and associative activities. Please wander.

hh.scd

SynthDef(\hh, {
    arg amp=(-10), out=0, freq=500, tone=7000, rel=0.5, rq=0.3;
    var sig, env;
    env = Env.perc(0.001,rel, curve:[8,-4]).ar(Done.freeSelf);
 
    sig = Saw.ar([123,150,180,219,240,261]).sum;
    sig = HPF.ar(sig, 400);
    sig = LPF.ar(sig, XLine.ar(10000,410, rel/2));
    sig = BPF.ar(sig, tone.lag(5), 0.07, 1.8);
    sig = (sig *(1+Env.perc(0.01, rel,9, curve:-8).ar)).tanh;
    sig = sig * -10.dbamp;
    sig = RHPF.ar(sig, 3500, rq);
    sig = sig * env * amp.dbamp.lag(5);
    sig = Pan2.ar(sig);
    Out.ar(out,sig);
}).add;

kick.scd

SynthDef(\k, {
    arg out=0, amp=(-5);
    var sig, env;
    sig = SinOsc.ar(Env.perc(0.001, 0.3, curve:-8).ar.linexp(0,1,30,250));
    sig = sig + (SinOsc.ar(Env.perc(0.00,0.01).ar.linexp(0,1,1000,8000),0,1) * Env.perc(0.001,0.01).ar);
    sig = sig *(1 + Env.perc(0.01,0.7).ar);
    sig = sig.tanh;
    env = Env.perc(0.001, 1).ar(Done.freeSelf);
    sig = sig *env *amp.dbamp.lag(3);
    sig = Pan2.ar(sig);
    Out.ar(out,sig);
}).add;

pitch.scd

SynthDef(\pitch, {
    arg in, pitch=1.0, lpf=4500, mix=0, amp=(-3), out=0;
    var dry, wet, temp, sig;
 
    dry = In.ar(in, 1);
    /*temp = In.ar(in, 1);*/
 
    wet = PitchShift.ar(dry, 0.2, pitch.lag(1.5), LFNoise2.ar(0.2).linlin(-1,1,0.0,0.2));
    sig = XFade2.ar(dry, wet, mix*2-1, amp.dbamp.lag(1));
    // sig = wet *amp.dbamp.lag(1);
 
    Out.ar(out,sig);
}).add;

satu.scd

SynthDef(\satu, {
    arg in, amp=(-3), out=0, saturation=1.1, mix=0, freqLpf=10000, freqHpf=40;
    var dry, wet, sig;
 
    dry = In.ar(in, 1);
    wet = (dry * saturation).tanh(1);
 
    sig = XFade2.ar(dry, wet, mix*2-1);
    sig = LPF.ar(sig, freqLpf.lag(2));
    sig = HPF.ar(sig, freqHpf.lag(2));
    sig = sig*amp.dbamp.lag(2);
 
    Out.ar(out,sig);
}).add;